home *** CD-ROM | disk | FTP | other *** search
/ Cream of the Crop 1 / Cream of the Crop 1.iso / PROGRAM / DJLGR106.ARJ / TRIDNT89.ASM < prev    next >
Assembly Source File  |  1992-04-08  |  4KB  |  229 lines
  1. ; This is file TRIDNT89.ASM
  2. ;
  3. ; Copyright (C) 1991 DJ Delorie, 24 Kirsten Ave, Rochester NH 03867-2954
  4. ;
  5. ; This file is distributed under the terms listed in the document
  6. ; "copying.dj", available from DJ Delorie at the address above.
  7. ; A copy of "copying.dj" should accompany this file; if not, a copy
  8. ; should be available from where this file was obtained.  This file
  9. ; may not be distributed without a verbatim copy of "copying.dj".
  10. ;
  11. ; This file is distributed WITHOUT ANY WARRANTY; without even the implied
  12. ; warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
  13. ;
  14.  
  15. cseg    segment    byte public 'code'
  16.     assume    cs:cseg, ds:cseg, es:cseg, ss:nothing
  17.  
  18.     dw    offset init_routine
  19.     dw    offset paging_routine
  20.     dw    0    ; set to 1 if separate read & write windows or
  21.             ; only 64K of video RAM (ie: no paging)
  22.  
  23. def_tw    dw    80    ; filled in by go32 if GO32 env. var. is set
  24. def_th    dw    25
  25. def_gw    dw    640
  26. def_gh    dw    480
  27.  
  28. ;--------------------------------------------------------------------------
  29. ; Entry: AX=mode selection
  30. ;        0=80x25 text
  31. ;        1=default text
  32. ;        2=text CX cols by DX rows
  33. ;        3=biggest text
  34. ;        4=320x200 graphics
  35. ;        5=default graphics
  36. ;        6=graphics CX width by DX height
  37. ;        7=biggest non-interlaced graphics
  38. ;        8=biggest graphics
  39. ;
  40. ; NOTE: This runs in real mode, but don't mess with the segment registers.
  41. ;
  42. ; Exit:  CX=width (in pixels or characters)
  43. ;        DX=height
  44.  
  45. init_table    label    word
  46.     dw    offset init_0
  47.     dw    offset init_1
  48.     dw    offset init_2
  49.     dw    offset init_3
  50.     dw    offset init_4
  51.     dw    offset init_5
  52.     dw    offset init_6
  53.     dw    offset init_7
  54.     dw    offset init_8
  55.  
  56. init_routine    proc    far
  57.     cmp    ax,8
  58.     jbe    valid_req
  59.     ret
  60. valid_req:
  61.     shl    ax,1
  62.     mov    bx,ax
  63.     jmp    init_table[bx]
  64.  
  65. init_0: ; 80x25 text
  66.     mov    ax,3
  67.     int    10h
  68.     mov    cx,80
  69.     mov    dx,25
  70.     ret
  71.  
  72. init_1: ; default text
  73.     mov    cx,def_tw
  74.     mov    dx,def_th
  75.     jmp    init_2
  76.  
  77. init_2_table    label    word
  78.     dw    01h, 40, 25
  79.     dw    03h, 80, 25
  80. init_2_tend    label    word
  81.  
  82. init_2: ; CX*DX text
  83.     mov    si,offset init_2_table
  84. init_2a:
  85.     cmp    [si+2],cx
  86.     jb    init_2b
  87.     cmp    [si+4],dx
  88.     jb    init_2b
  89.     ; got a big enough one!
  90.     jmp    init_2c
  91. init_2b:
  92.     cmp    si,offset init_2_tend - 6
  93.     je    init_2c
  94.     add    si,6
  95.     jmp    init_2a
  96. init_2c:
  97.     mov    ax,[si]
  98.     push    si
  99.     int    10h
  100.     pop    si
  101.     mov    cx,[si+2]
  102.     mov    dx,[si+4]
  103.     ret
  104.  
  105. init_3: ; biggest text
  106.     mov    ax,[init_2_tend-6]
  107.     int    10h
  108.     mov    cx,[init_2_tend-4]
  109.     mov    dx,[init_2_tend-2]
  110.     ret
  111.  
  112. init_4: ; 320x200 graphics
  113.     mov    ax,13h
  114.     int    10h
  115.     mov    cx,320
  116.     mov    dx,200
  117.     ret
  118.  
  119. init_5: ; default graphics - should be 640x480 if supported
  120.     mov    cx,def_gw
  121.     mov    dx,def_gh
  122.     jmp    init_6
  123.  
  124. init_6_table    label    word
  125.     dw    13h, 320, 200
  126.     dw    5ch, 640, 400
  127.     dw    5dh, 640, 480
  128.     dw    5eh, 800, 600
  129.     dw    62h, 1024, 768
  130. init_6_tend    label    word
  131.  
  132. init_6: ; CX*DX graphics
  133.     mov    si,offset init_6_table
  134. init_6a:
  135.     cmp    [si+2],cx
  136.     jb    init_6b
  137.     cmp    [si+4],dx
  138.     jb    init_6b
  139.     ; got a big enough one!
  140.     jmp    init_6c
  141. init_6b:
  142.     cmp    si,offset init_6_tend - 6
  143.     je    init_6c
  144.     add    si,6
  145.     jmp    init_6a
  146. init_6c:
  147.     mov    ax,[si]
  148.     push    si
  149.     int    10h
  150.     pop    si
  151.     mov    cx,[si+2]
  152.     mov    dx,[si+4]
  153.     ret
  154.  
  155. init_7: ; biggest non-interlaced graphics
  156.     mov    ax,5eh
  157.     int    10h
  158.     mov    cx,800
  159.     mov    dx,600
  160.     ret
  161.  
  162. init_8: ; biggest graphics
  163.     mov    ax,62h
  164.     int    10h
  165.     mov    cx,1024
  166.     mov    dx,768
  167.     ret
  168.  
  169. init_routine    endp
  170.  
  171. ;--------------------------------------------------------------------------
  172. ; Entry: AH=read page
  173. ;        AL=write page
  174. ;
  175. ; NOTE: This runs in protected mode!  Don't mess with the segment registers!
  176. ; This code must be relocatable and may not reference any data!
  177. ;
  178. ; Exit: VGA configured.
  179. ;       AX,BX,CX,DX,SI,DI may be trashed
  180. ;
  181. ; Code derived from VGAKIT version 3.4
  182. ;    Copyright 1988,89,90 John Bridges
  183.  
  184.     assume    ds:nothing, es:nothing
  185.  
  186. paging_routine    proc    far
  187.     mov    cx,ax
  188.     mov    dx,3ceh        ;set page size to 64k
  189.     mov    al,6
  190.     out    dx,al
  191.     inc    dl
  192.     in    al,dx
  193.     dec    dl
  194.     or    al,4
  195.     mov    ah,al
  196.     mov    al,6
  197.     out    dx,al
  198.     inc    dx
  199.     xchg    ah,al
  200.     out    dx,al
  201.     dec    dx
  202.         
  203.     mov    dl,0c4h        ;switch to BPS mode
  204.     mov    ax,000bh
  205.     out    dx,al
  206.     inc    dx
  207.     xchg    ah,al
  208.     out    dx,al
  209.     dec    dx
  210.     in    al,dx
  211.  
  212.     mov    ah,cl
  213.     xor    ah,2
  214.     mov    dx,3c4h
  215.     mov    al,0eh
  216.     out    dx,al
  217.     inc    dx
  218.     xchg    ah,al
  219.     out    dx,al
  220.     dec    dx
  221.  
  222.     ret
  223. paging_routine    endp
  224.  
  225. ;--------------------------------------------------------------------------
  226.  
  227. cseg    ends
  228.     end
  229.